Hi Developers, Welcome again! In this post we are going to learn how we can create/update custom metadata using apex class.

As we know that it is not similar to create/update metadata using apex like Custom Setting OR Custom/Standard Object.

To create/update Custom Metadata we need to deploy the custom metadata using DeployCallback interface and it’s required methods.

So, let’s start doing the development. You need to follow the below simple steps.

Step 1 – Create Custom Metadata

Navigate to Setup -> Develop -> Custom Metadata Types -> New Custom Metadata Types -> Create the Custom Metadata. I have created label as Profile Setting. Refer below Screenshot

Step 2 – Create a class and implement Metadata.DeployCallback interface

public class CreateUpdateMetadataUtils implements Metadata.DeployCallback {
    
}

Step 3 – implement handleResult method in the class

After you have implemented the DeployCallback interface you need to provide the implementation of handleResult method. Below is the code for the same

public class CreateUpdateMetadataUtils implements Metadata.DeployCallback {
    /* Below method recieves the 2 parameters 
       1 - Metadata.DeployResult => Object of MetadataContainer class where this method has been implemented.
       2 - Metadata.DeployCallbackContext => Object of the class where this method has been implemented
   */
    public void handleResult(Metadata.DeployResult result,
                             Metadata.DeployCallbackContext context) {
        if (result.status == Metadata.DeployStatus.Succeeded) {
            // Deployment was successful
        } else {
            // Deployment was not successful
        }
    }
}

Step 4 – Prepare the Custom Metadata

Now, as you have done the above step now time is to prepare the custom Metadata for this create the Object of Metadata.CustomMetadata like below

Metadata.CustomMetadata customMetadata =  new Metadata.CustomMetadata();
customMetadata.fullName = 'Profile_Setting.Admin';
customMetadata.label = 'Admin';

Value for fullName of Metadata we need to provide the Qualified Name. For example, if the object name of Metadata is Profile_Setting then and you wanted to create a record named Admin then the full name will look like ‘Profile_Setting.Admin‘

Point to keep in mind

Step 5 – Add field values to the Metadata Record

We have create the Object of Custom Metadata and then also provided the fullName(MasterLabel). Now, use the below code to provide the value for the custom fields. Below is the Code

/* Create the Object of CustomMetadataValue */
Metadata.CustomMetadataValue customField = new Metadata.CustomMetadataValue();
/* Provide the API Name of the Field like Admin__c */
customField.field = 'Profile_Full_Name__c';
/* Provide the value for the field */
customField.value = 'Admin';
/* Add this field to the Metadata That we created */ 
customMetadata.values.add(customField);

/* If you wanted to add more than one field you need to repeat the above step OR You can use Map<String, Object> where Key is the Field API Name and value is the value for the field */

/* In my example, I will create a separate method which is responsible for deploying the Custom Metadata Record */

See the code comments.

Step 6 – Create a Deploy Container

Till now we have performed the below steps

• Create Custom Metadata
• Create a Class that implements Metadata.DeployCallback interface
• Implement the handleResult method
• Prepare the Custom Metadata with the fullName (MasterLabel)
• Add values to the Custom Metadata

Let’s create a deploy container which will be responsible for deploying the Custom Metadata Record. Create the DeployContainer class Object

Metadata.DeployContainer mdContainer = new Metadata.DeployContainer();

Add the Custom Metadata in the DeployContainer using addMetadata method

mdContainer.addMetadata(customMetadata);

Step 7 – Deploy the Custom Metadata

Use below code to deploy the custom metadata that we have prepared above

1 – Create the Object of our class

CreateUpdateMetadataUtils callback = new CreateUpdateMetadataUtils();

2 – Deploy the metadata using below code

Id jobId = Metadata.Operations.enqueueDeployment(mdContainer, callback);

Here is the Final and Complete Class

public class CreateUpdateMetadataUtils implements Metadata.DeployCallback {
    
    public void handleResult(Metadata.DeployResult result, Metadata.DeployCallbackContext context) {
        if (result.status == Metadata.DeployStatus.Succeeded) {
            System.debug(' success : '+ result);
        } else {
            System.debug(' fail : '+ result);
        }
    }
    
    public static void createUpdateMetadata(String fullName, String label, Map<String, Object> fieldWithValuesMap){
        Metadata.CustomMetadata customMetadata =  new Metadata.CustomMetadata();
        customMetadata.fullName = fullName;
        customMetadata.label = label;
        
        for(String key : fieldWithValuesMap.keySet()){
            Metadata.CustomMetadataValue customField = new Metadata.CustomMetadataValue();
            customField.field = key;
            customField.value = fieldWithValuesMap.get(key); 
            customMetadata.values.add(customField);
        }
        
        Metadata.DeployContainer mdContainer = new Metadata.DeployContainer();
        mdContainer.addMetadata(customMetadata);
        CreateUpdateMetadataUtils callback = new CreateUpdateMetadataUtils();
        Id jobId = Metadata.Operations.enqueueDeployment(mdContainer, callback);
    }
}

Test the code

Run the below code from Developer Console

Map<String, Object> maptest = new Map<String, Object>();
maptest.put('Is_Admin__c',true);
maptest.put('Profile_Full_Name__c','Admin');
maptest.put('Profile_Name__c','Admin');
maptest.put('Updated__c',false);
CreateUpdateMetadataUtils.createUpdateMetadata('Profile_Setting.TEST_AMIT','TEST_AMIT',maptest);

Go to Setup -> Deploy -> Deployment Status -> and check if you are getting success message or NOT

Navigate to the custom metadata and then make sure that metadata has been created or not.

#Salesforce #SFDCPanther @cloudyamit sfdcpanther@gmail.com

Resource

• Salesforce Document
• Trailhead Module
• Trailhead Module